ftp-backup: func [local-folder ftp-folder /verbose /local i] [

    i: 0
    if not exists? ftp-folder [
      make-dir/deep ftp-folder
        either verbose [
          print form [ftp-folder "folder created ..."]
        ][
          print i
        ]
    ]
    foreach file read local-folder [
        i: i + 1
        either find file "/" [
            ftp-backup local-folder/:file ftp-folder/:file
        ][
            either verbose [
              print file
            ][
              print i
            ]
            write/binary ftp-folder/:file read/binary local-folder/:file
        ]
    ]
]

To use it for example on Dreamhost FTP Server for example, type:

ftp-copy %"/c/install/wordpress/" ftp://ftpuser:ftppassword@maindomain.com/reboltutorial.com/

Note: to have ftp-backup available at startup, store it in user.r.

0 people like this post.

Like 

Bookmark this

Let’s say you want to parse this:

content: {<tag attribute1="valueattribute1" attribute2="valueattribute2">
</tag>
<tag attribute2="valueattribute21" attribute1="valueattribute11" >
</tag>
}

or

content: {<tag attribute1="valueattribute1" attribute2="valueattribute2">
</tag>
<tag attribute2="valueattribute21">
</tag>
}

If you try this rule …

attribute1: [{attribute1="} copy valueattribute1 to {"} thru {"}]
attribute2: [{attribute2="} copy valueattribute2 to {"} thru {"}]

attributes-rule: [attribute1 attribute2 (print valueattribute1 print valueattribute2 )
| attribute2 attribute1(print valueattribute2 print valueattribute1)
]

rule: [any [to {<tag } thru {<tag } attributes-rule {>} to {</tag>} thru {</tag>}] to end]

… the second content won’t fully parse. Instead you have to add none keywords like this:

attribute1: [{attribute1="} copy valueattribute1 to {"} thru {"}]
attribute2: [{attribute2="} copy valueattribute2 to {"} thru {"}]

attributes-rule: [[attribute1 | none] [attribute2 | none] (print valueattribute1 print valueattribute2
valueattribute1: none valueattribute2: none)
| [attribute2 | none] [attribute1 | none] (print valueattribute2 print valueattribute1
valueattribute1: none valueattribute2: none
)
| none
]

rule: [any [to {<tag } thru {<tag } attributes-rule {>} to {</tag>} thru {</tag>}] to end]

If you test content 2 with last rule, you should get

>> parse content rule
valueattribute1
valueattribute2
none
valueattribute21
== true
>>

0 people like this post.

Like 

Bookmark this

So let’s say I have a list of programs I want to launch by just typing a keyword in Rebol Shell. For example, Notepad would launch my favorite notepad2 program in c:\program files\notepad2\notepad2.exe. So I created a file list shell.list.txt to store them as a sample:

"notepad" "c:\program files\notepad2\notepad2.exe"
"calc" "c:\windows\system32\calc.exe"
"WebDevExpress" "C:\Program Files\Microsoft Visual Studio 9.0\Common7\IDE\VWDExpress.exe"

If this file is located in data sub-directory within the current directory (generally the directory of the current script that is executing), it will be loaded into a Rebol block with this instruction:

shell.list: load %data/shell.list.txt

Then the run function will refer to it to get the real path with the Rebol Select function:

Run: func[exe-path][
  if/else not none? it: select shell.list exe-path [
	call quote it
  ][
        ;in case keyword cannot be found, one supposes it's the full path
	call quote exe-path
  ]
]

Copy and paste it into Rebol Console along with this mock data:

shell.list: ["notepad" "c:\program files\notepad2\notepad2.exe"
"calc" "c:\windows\system32\calc.exe"
"WebDevExpress" "C:\Program Files\Microsoft Visual Studio 9.0\Common7\IDE\VWDExpress.exe"]

So that you can test it by typing

run "c:\windows\system32\calc.exe"

or just the keyword

calc

This latter won’t work. Why? Because calc has not yet been defined as a command in Rebol. To do so, you would create a calc function like this:

calc: func[][
    run "c:\windows\system32\calc.exe"
]

Copy and paste the code above and test calc again, this time it should work.

Now, it would be tedious to define each keyword by creating a new function by hand whereas the procedure is rather generic. So naturally you’d like to use a dynamic generator function to do this for you something like this:

foreach [name path] shell.list [
	func-body: to-block rejoin ['run " " {"}  name {"}]
	set (to-word name) make function! [] func-body
]

If you execute the code above, you could see that it created notepad and calc functions by using the rebol source command:

>> source notepad
notepad: func [][run "notepad"]
>> source calc
calc: func [][run "calc"]
>>

Now if you want to test the calc keyword again, you would get this bad “surprise”:

>> calc
** Script Error: run word has no context
** Where: calc
** Near: run "calc"

because run is an unknown word within the context of func-body you created at runtime within the foreach loop. So you have to bind run to the func-body context by using the bind function like this:

set (to-word name) make function! [] bind func-body 'run

so that you can copy and paste the foreach loop once again:

foreach [name path] shell.list [
	func-body: to-block rejoin ['run " " {"}  name {"}]
	set (to-word name) make function! [] bind func-body 'run
]

Finally typing the calc keyword in Rebol Console should launch the calculator !

To have all this automatically at Rebol launch, put these functions in User.r.

0 people like this post.

Like 

Bookmark this

It’s a gentle but rather complete course to Rebol language which will give you a good background to understand other books like the one from Olivier Auverlot and Peter Wood or tutorials on rebol tutorial or elsewhere like the excellent musiclessonz now re-bol.com.

0 people like this post.

Like 

Bookmark this

And a few days ago, HostileFork has whispered me that in a future release of Rebol 2, you will have nothing less than ODBC, SSL/HTTPS, in fact it is as if you had Rebol Command for FREE. That is not only great, that is unexpected so I say Wow to RT!

What you can do with ODBC ? Well you can edit MS Access Database with your Rebol 500Ko (instead of dozens of megabytes just for the GUI part, of course the data size will stay as big) or you can use secure SSL with twitter API and other webservices, only imagination is the limit :).

Just have all of us to wait for it except if you join Altme World or Qtask at the moment as it is in beta stage.

Update January 19th: From the link given by Petr
http://www.rebol.com/docs/v2-7.html

* View/Pro features enabled: allowing SSL, ODBC, and encryption
* Adds R2/Forward mezzanine functions (from Brian Hawley)
* Re-enables installation and proper view-root startup (appdata dir on Win32)
* Install and uninstall added to ViewTop GUI panels
* Fixes LOAD with PORTS that return strings to be loaded as blocks.
* Fixes Decode-CGI for url-encoded variables (e.g. used by Flash)
* Fixes Strict-not-equal? of integers and adds != and !== operators

0 people like this post.

Like 

Bookmark this

We have in fact already seen how to call a Rebol CGI from PHP, it’s now time to look at message passing from PHP to Rebol (the return message stays the same: the output of Linux/Windows standard I/O).

Let’s take the example of a search form. Instead of posting to Rebol CGI from the html form embedded in an HTML Page like this:

	<form method="get" id="searchform_bottom" action="search.cgi">
            <div>
                <input type="text" value="" size="41" name="s" />
				<input type="submit" id="searchsubmit_bottom" value="Search" />

            </div>
        </form>

We would put the form in an index.php page and call the same index.php from the form

	<form method="get" id="searchform_bottom" action="index.php">
            <div>
                <input type="text" value="" size="41" name="s" />
				<input type="submit" id="searchsubmit_bottom" value="Search" />

            </div>
        </form>

then within index.php we would test for the existence of the $_GET['s'] variable or not and forward to search.cgi passing the search term and any other other parameters we want by separating them with space, for example below, we also pass the command “search” at the end (this could be usefull if we have several kind of actions):

<?php
if (!isset($_GET['s'])) {
  $command= './cgi-bin/index.cgi';
  echo system($command);
}
else {
  $searchterm = $_GET['s'];
  $command= './search.cgi '. '"' . $searchterm . '"' . ' ' . '"' . 'search' . '"';
  echo system($command);
}
?>

On Rebol’s side we just have to pick the search term from the first element of system/options/args block (Rebol’s array):

#!/home/yourhostingaccount/yourdomain/rebol/rebol -c
REBOL [Title: "Search"]
  command-line: system/options/args
  search-term: pick command-line  1
]

If we want we could even make the script work in both context RPC or CGI by testing system/options/cgi/remote-addr:

#!/home/yourhostingaccount/yourdomain/rebol/rebol -c
REBOL [Title: "Search"]

test-remote: system/options/cgi/remote-addr;
;write/append/lines %log.txt mold test-remote
;write/append/lines %log.txt mold system/options/args

if/else (none? test-remote) [
  command-line: system/options/args
  search-term: pick command-line  1
][
  print "content-type: text/html^/"
  ;==========================
  do %cgi.lib.r
  cgi: get-cgi
  ;write/append/lines %log.txt mold cgi
  ;==========================
  search-term: cgi/s
  ;write %log.txt search-term
]

Of course this is just the basis of RPC between PHP and Rebol. A more standard serialization format could be defined furthermore using Rebol format or any other like JSON.

This is simple and flexible so that mixing PHP and Rebol should be a pleasure for both lovers of one language or the other while ripping the benefits from both sides : no more languages war :).

0 people like this post.

Like 

Bookmark this

I will inspire from Douglas Crockford, who told that Rebol had been part of JSON inspiration and who has written in the past this famous article on Javascript: “Why Javascript is the most misunderstood language”, since Javascript has now won a huge gain in respect, the most misunderstood language is now Rebol. Is it for the same reasons ?

The Name

Rebol is the acronym of Relative Expression Based Object Language and also associated with the “Rebolution” slogan. Nice name and slogan which would perfectly suit the Geeks mentality. So for me the problem didn’t come from the name, it did come from the unrealistic goal to pretend that Rebol could be everywhere. Instead of showing how on Real World Projects, there were just bold claims. This is Marketing 101: Don’t tell, Show. The World is still waiting for the Rebolution to demonstrate let’s say that a Twitter clone in Rebol could support massive concurrent users :).

Lisp in C’s Clothing (for Javascript) - Lisp without Clunky Parenthesis
Rebol is explicitely descending from Lisp with a much more expressive syntax. That was also a good point for Rebol so why did it fail to attract people on that ? Rebol didn’t target IT professionals, it did try to target the average hobbyists pretending that the language was easy. In truth on the surface Rebol is easy but as you try to go deeper, things become harder because in concepts, Lisp and Functional Programming mixed with OOP is not for the faint-hearted. Instead of explaining the hard concepts, all documentation tend to just explain the easy ones, guarding the “secrets” for the “smarts” who would dare to ask the right questions. Whereas VID/AGG are really the Gems in Rebol with the Parse Function, the VID documentation is the most lacking on that point so that even attempting to create a simple centered dialog box is difficult not because it’s impossible but because it isn’t explained anywhere, you have to try to understand by yourself by looking at the source code of the editor (supposing you discovered how) and in fact I encountered some problem that is still unsolved. As for AGG of course, you can expect even less - to say the least :).

Not Opensource I’m not so much naïve as to believe that the Opensource movement is only a spontaneous group of benevolent people because in Economics History, deflating the price of goods is a well-known scheme from the Big Capitalists to kill their numerous small competitors before they soar the price again or drive the investment towards another large scale sector they will be the only one to control (Oil in the past, Cloud-Computing tomorrow) so I’m not the one who would blindly say: go Opensource. The reason to go Opensource is due to this huge Marketing Scheme that these same Software Giants Oligopoly have setup behind the scene that is killing yourself financially little by little if you don’t want to follow the same path. Not going Opensource means a Heavy Cost for promoting your product because you cannot make free publicity. Since Marketing Cost is much larger in proportion than Production Cost for many successfull companies, you won’t be able to finance any growth. Not going fully Opensource or at least not giving “enough” to the Opensource Product from the commercial product is not a clear message for the Opensource lovers, that may be yet another mistake.

Targeting Language/Virtual OS Platform Market. Yesterday Rebol’s ambition was to be an Ubiquitous Language or maybe worst to be a Virtual OS Platform. A Language has no perceived value today only Reusable Frameworks and Libraries (look at Jquery and its sponsors once again or PHP Zend Framework). OS Platforms are only for the Big Names, we know them already: Java VM (not the language) and .NET (once again not the languages). Instead of creating an “IronRebol” like an IronPython, IronRuby, Clojure or Scala, Rebol still pretends to be multiplatform. Being Multiplatform without being able to integrate with the two main Virtual OS Platforms is not really multiplatform in my opinion. This is for me the number One Strategic error. Not exploiting the Ecosystem of Dynamic Languages that are now openly favored by both the Giants Sun and Microsoft (see Microsoft DLR initiative for example) will be a huge mistake because as usual time is your number One Ennemy and the door may close soon as the Winners will be emerging from this new Competitive race. And I almost forget that this also would save hugely on Marketing cost.

There are many other things, some I said in other articles or section but to make things short, I will now jump to the conclusion: Rebol is worth a look for sure and I will continue to do so, but its Business Strategy is just not really marketable in its current state. A 180° turn is needed, so not easy but not quite impossible yet, I still believe :).

Bookmark this

protect 'zip

The problem is I may myself need this library somewhere else by reloading it in some script and this will create this disgracefull interruption:

** Script Error: Word zip is protected, cannot modify

So as to avoid this problem, I have created this set-once function:

set-once: func[word [word!] value /verbose][
    if/else error? error: try [set word value][
        disarm error
        if verbose [
            print [ "cannot set" word]
            none
        ]
    ][value]
]

This function will either return the value or none if the word is protected:

>> set-once/verbose 'zip "test"
cannot set zip
== none
>>

This doesn’t solve all problems and the best would be to override the set function but it will be for next time as it’s too tedious to do so in current version of Rebol when there are multiple refinements (see here).

0 people like this post.

Like 

Bookmark this

to-js Product

or for a more refined version (see at the end of the article):

to-js/prototype Product

where Product is just an example of an Object you will create by typing minimistically:

Class Product [
   Id: 1
   ProductName: "Orange"
]

The result will be copied directly to the clipboard with a nicely indented javascript code:

function Product() {

	this.Id=1;
	this.ProductName="Orange";

	this.getId = function() {
		return this.Id;
	}

	this.getProductName = function() {
		return this.ProductName;
	}

}

The source code to generate js code is below and you can adapt it furthermore to suit your own coding style (see at the end a more refined version for prototype):

to-js: func['ObjectName [Word!] /local Obj body javascript-code][

  if not value? 'class [
      ;load oop library
      do http://reboltutorial.com/oop
  ]

  Obj: get ObjectName
  Body: third Obj

  javascript-code: rejoin [
    "function " ObjectName "() {"
     newline newline
  ]

  Foreach [property value] Body [
    if (type? value) = string! [
        value: rejoin [{"} value {"}]
    ]
    append javascript-code rejoin [
      tab "this." property "=" value ";" newline
    ]
  ]

  append javascript-code rejoin [newline]

  Foreach [property value] Body [
    append javascript-code rejoin [
      tab "this.get" property " = function() {" newline
      tab tab "return this." property ";" newline
      tab "}"
      newline
      newline
    ]
  ]

  append javascript-code rejoin ["}" newline]

  write clipboard:// javascript-code
]

The instruction

do http://reboltutorial.com/oop

loads our class and extend function to create our Product as already seen:

Class Product [
   Id: 1
   ProductName: "Orange"
]

Or add properties dynamically to your object before converting it with to-js:

extend Product [
    CategoryId: 1
]
to-js Product

which will then copy this js snippet to the clipboard:

function Product() {

	this.Id=1;
	this.ProductName="Orange";
	this.CategoryId=1;

	this.getId = function() {
		return this.Id;
	}

	this.getProductName = function() {
		return this.ProductName;
	}

	this.getCategoryId = function() {
		return this.CategoryId;
	}

}

A more refined version of the script is to accept the prototype (or proto for shortcut) to be able to output the prototype syntax version:

to-js: func['ObjectName [Word!] /proto /Prototype /local Obj body javascript-code][

  if not value? 'class [
      ;load oop library
      do http://reboltutorial.com/oop
  ]

  Obj: get ObjectName
  Body: third Obj

  javascript-code: rejoin [
    "function " ObjectName "() {"
     newline newline
  ]

  Foreach [property value] Body [
    if (type? value) = string! [
        value: rejoin [{"} value {"}]
    ]
    append javascript-code rejoin [
      tab if/else (not any [proto prototype])
      [ "this"][rejoin [ObjectName ".prototype"]] "." property "=" value ";"
      newline
    ]
  ]

  append javascript-code rejoin [newline]

  Foreach [property value] Body [
    append javascript-code rejoin [
      tab if/else (not any [proto prototype])
      [ "this"][rejoin [ObjectName ".prototype"]]
      ".get" property " = function() {" newline
      tab tab "return this." property ";" newline
      tab "}"
      newline
      newline
    ]

  ]

  append javascript-code rejoin ["}" newline]

  write clipboard:// javascript-code
]

Output:

function product() {

	product.prototype.Id=1;
	product.prototype.ProductName="Orange";

	product.prototype.getId = function() {
		return this.Id;
	}

	product.prototype.getProductName = function() {
		return this.ProductName;
	}

}

For a tutorial on Javascript OOP see for example this article or this article.

Bookmark this

get-env "JAVA_HOME"
get-env "CLASSPATH"
get-env "JRE_HOME"
get-env "CATALINA_HOME"

To parse your environment variable, just use parse/all (do not forget /all otherwise space will be also taken as delimiter):

parse/all get-env "CLASSPATH" ";"

which will output something like this:

>> parse/all get-env "CLASSPATH" ";"
== ["." {t:\tomcat\lib\servlet.jar}]

So if you want to check that you did have current path “.” in your classpath, you would check it like this (do not omit /all refinement once again):

if none? find (parse/all get-env "CLASSPATH" ";") "." [
    print "Don't forget to add current path to your CLASSPATH ! "
]

Same if you want to check that you have added javac, java, PHP or whatever in your PATH environment variable:

if none? find (parse/all get-env "PATH" ";") "jdk" [
    print "Don't forget to add Javac dir in your PATH ! "
]

if none? find (parse/all get-env "PATH" ";") "jre" [
    print "Don't forget to add Java dir in your PATH ! "
]

if none? find (parse/all get-env "PATH" ";") "PHP" [
    print "Don't forget to add PHP dir in your PATH ! "
]

To ease the syntax, you can put this function in your user.r file:

check-env-path: func[what /local result][
    if/else none? result: find (parse/all get-env "PATH" ";") what [
        print [ rejoin [{"} what {"}] "not found in your PATH Environment Variable ! "]
    ][print result]
]

and call it like this:

check-env-path "PHP"

which would output for example:

>> check-env-path "PHP"
"PHP" not found in your PATH Environment Variable !
>>

For a list of Windows Environment variables see Vista Environment Variables and XP Environment Variables (TEMP or TMP variable, …). For example, APPDATA may contain your Rebol user.r file depending on the version of Rebol and OS.

To get the path of Windows/System32 use this trick (does function is synonym of func without the need to pass arguments):

system32-dir: does [
    path: get-env "COMSPEC"
    until [(rest: back remove back tail path) =  "\"]
    head rest
]

So if want to call the Environment Variables Control Panel from Rebol Console, you could create this function:

env-panel: does[
    call rejoin [ {"}  system32-dir "SystemPropertiesAdvanced.exe"  {"}]
]

And to call ODBC32 from Rebol Console, you could create this function:

ODBC32: does [
    call rejoin [ {"}  system32-dir "odbcad32.exe"  {"}]
]

0 people like this post.

Like 

Bookmark this